scripts/preprocess


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

#!/usr/bin/awk -f

function ansi(s) {
	if (s == "none" || s == "NONE") {
		return s
	}

	return s "_ansi"
}

function tpl(s) {
	if (s == "none" || s == "NONE") {
		return "NONE"
	}

	return "{{ " s " }}"
}

function strip_underscore(s) {
	if (substr(s, 1, 1) == "_") {
		return substr(s, 2)
	}

	return s
}

/^#/ { $0 = "\"" substr($0, 2) }

/^[_[:upper:]]/ && NF == 3 {
	$0 = "hi " strip_underscore($1) " guifg=" tpl($2) \
	   " ctermfg=" tpl(ansi($2)) " guibg=" tpl($3) \
	   " ctermbg=" tpl(ansi($3)) " cterm=NONE"
}

/^[_[:upper:]]/ && NF > 3 {
	line = "hi " strip_underscore($1) " guifg=" tpl($2) \
	     " ctermfg=" tpl(ansi($2)) " guibg=" tpl($3) \
	     " ctermbg=" tpl(ansi($3)) " cterm="

	for (i=4; i <= NF; i++) {
		line = line $i

		if (i < NF) {
			line = line ","
		}
	}

	$0 = line
}

/^[_[:upper:]]/ && NF == 2 { $0 = "hi! link " strip_underscore($1) " " $2 }

{ print }